IcaroFilho

Boa noite Pedro.
tentarei de resumir de forma bem simples.
vc utilizará o “se”, sempre determinada situação tiver mais de uma opção.
ex.: Supondo que passa com um veiculo por um radar:

programa {
	funcao inicio() {
		inteiro vel = 60
		se (vel > 70){
		    escreva("Velcidade superior a 70 km/h") // bloco 1
		} senao {
		    escreva("Velocidade inferior a 70 km/h") // bloco 2
		}
	}
}

Ou seja, se o veiculo estiver acima de 70, executará o bloco 1 e não executará o resto de se.
Neste exemplo, o valor de vel é inferior a 70, logo ele faz o teste no se, como a condição é falsa ele executa automaticamente o senao

Se nos criássemos vários ” SE “. todas as condições verdadeiras seriam atendidas.
por exemplo.: Suponha que queiramos que o programa nos informe que o veiculo esta abaixo de determinada velocidade. se utilizarmos apenas o se:

inteiro vel = 30
se (vel < 10){
    escreva("Velocidade menor que 10\n")
}
se (vel < 20){
    escreva("Velocidade menor que 20\n")
}
se (vel < 40){
    escreva("Velocidade menor que 40\n")
}
se (vel < 50){
    escreva("Velocidade menor que 50\n")
}

isso nos daria uma saida:

Velocidade menor que 40
Velocidade menor que 50

sabendo que 40 é menor que 50, fica desnecessário continuar os testes lógicos. Sempre que utilizarmos múltiplas opções, usaremos senao se:

		inteiro vel = 30
		se (vel < 10){
		    escreva("Velocidade menor que 10\n")
		}
		senao se (vel < 20){
		    escreva("Velocidade menor que 20\n")
		}
		senao se (vel < 40){
		    escreva("Velocidade menor que 40\n")
		}
		senao se (vel < 50){
		    escreva("Velocidade menor que 50\n")
		}

output:
Velocidade menor que 40
Com isso, quando o teste logico for verdadeiro, irá encerrar.

Boa noite.
Atualmente seu código esta dando erro por falta de fechamento “(” na linha 12.
Matematica.arredondar(v,2)(v-(v*5/100)) -> Falta uma conexão aqui. (seja um operador aritmético ou uma concatenação)

Concertando o fechamento dará erro por falta de inicialização da variável v.
Isto porque já esta executando a variavel antes mesmo de declarar seu valor. Para corrigir pode atribuir um valor nulo a ela em sua declaração.
real v = 0.0
Corrigindo essas etapas seu exercicio continuará fora do padrão devido a desorganização. vamos arrumar por etapas.

1. Declaramos as variaveis que prentede usar. (no caso v e r)
   real v, r
2. depois fazemos a solicitação do valor ao usuário.

   escreva("Qual o preço do produto? ")
   leia(v)

3. Agora que temos o valor de v. podemos calcular o desconto.
   r = v - (v *0.05) (OBS: so simplifiquei a conta, que também pode ser r = v – (v * 5 / 100) )
4. agora que temos todos os parâmetros podemos dar a saída:
   escreva("Com 5% de desconto, o produto sai por R$ ", Matematica.arredondar(r, 2) )
5. Código completo:

   programa
   {
   	inclua biblioteca Matematica
   	
   	funcao inicio()
   	{
   		real v, r
   		
   		escreva("Qual o preço do produto? ")
   		leia(v)
   
   		r = v - (v *0.05)
   
   		escreva("Com 5% de desconto, o produto sai por R$ ", Matematica.arredondar(r, 2) )
   		
   	}
   }

• Esta resposta foi modificada 2 anos, 11 meses atrás por IcaroFilho.

Boa tarde Douglas.
Existe um tópico aberto por um aluno sobre este exercício Aqui
Sempre, antes de abrir um tópico, procure no fórum se não há algo referente a sua duvida. Neste caso sobre o mesmo exercício.

Referente a sua duvida.
você esta pegando o valor em metros m e multiplicando por mil. (10*10*10)

O correto seria dividir por mil -> 1 km = 1000 m

nesta operação de multiplicar por 1000, vc esta encontrando os milímetros.

Bom dia Marcos,
Primeiramente, antes de postar suas duvidas, tente procurar no fórum se a mesma duvida já não foi perguntada. Se houver e ainda continuar com duvidas, poste dentro do mesmo. Isto evita que o fórum fique poluído com muitas postagem do mesmo assunto | exercício.
LINK do mesmo exercício.

Referente a sua duvida.
Tem-se que traçar mentalmente o passo-a-passo do que é necessário para realizar.
A questão te pede para exibir apenas o primeiro nome, ou seja, ele te pede para extrair parte de string.
Ao pesquisar na biblioteca encontramos um metodo de extração:
funcao cadeia extrair_subtexto(cadeia cad, inteiro posicao_inicial, inteiro posicao_final)

sabemos que: cad => nome | posicao_inicial ==> 0 | posicao_final => índice final da string

Então nos falta saber qual é este índice. Para descobrirmos temos que saber a posição da ultima letra do primeiro nome.
e como sabemos como separar? simples, toda separação vem com uma coisa em comum, o espaço.
faremos uma busca para encontrarmos onde se tem o primeiro espaçamento pelo metodo:
funcao inteiro posicao_texto(cadeia texto, cadeia cad, inteiro posicao_incial)

sabemos que: texto => ” “ | cad => nome | posicao_inicial => 0

isto nos retornará o índice do espaçamento. Este índice que teremos que informar na extração do texto.

Segue abaixo o código refeito. Tente fazer antes de replica-lo.

programa
{
	inclua biblioteca Texto --> txt
	
	funcao inicio()
	{
		inteiro pos
		cadeia nome
		
		escreva("Digite seu nome completo: ")
		leia (nome)

		pos = txt.posicao_texto(" " , nome ,0)
		
		escreva("Seu primeiro nome é: " + txt.extrair_subtexto(nome,0,pos) )
	}
}

Bons estudos !!

Bom dia Antônio,
Primeiramente, não há necessidade de escrever todo o código em apenas uma linha.
Menor numero de linhas não quer dizer o código é melhor ou pior. E devido a linha ser extensa, a probabilidade de errar por falta de atenção e numa revisão é maior (tanto que isso ocorreu na sua DIFERENÇA, onde a operação seria subtração e realizou uma nova soma).

Quanto a sua divisão inteira, basta dividir um numero pelo outro (dividendo pelo divisor) que o resultado da divisão inteira será o quociente.
numero1/numero2, Contudo, por se tratar de dois números reais, sua divisão será em formato decimal. Para obtermos o quociente de forma inteira, necessitamos importar a biblioteca Tipos para podermos converter de formato real para inteiro.

inclua biblioteca Tipos --> tp
.
.
escreva("\n DIVISÃO INTEIRA = " + tp.real_para_inteiro(numero1/numero2))

Em ultimo lugar, não é que o portugol não esteja aceitando o %. O fato é que ele esta realizando a operação até o resto ser zero (por isso o quociente retornará , em sua maioria, com virgula).

Sendo assim tem-se que passa-los individualmente para inteiro e depois realizar a operação.
escreva("\n RESTO DA DIVISAO = " + tp.real_para_inteiro(numero1) % tp.real_para_inteiro(numero2))

Segue o código completo:

programa
{
	inclua biblioteca Tipos --> tp
	
	funcao inicio()
	{
		real numero1, numero2
		escreva(" { EXercício 004 - Operações Aritiméticas basicas }\n" + "Digite um valor: ")
		leia(numero1)
		escreva("Digite outro valor: ")
		leia(numero2)
		escreva("---------RESULTADO---------")
		escreva("\n SOMA = " + (numero1 + numero2))
		escreva("\n DIFERENÇA = " + (numero1 - numero2))
		escreva("\n PRODUTO = " + (numero1*numero2))
		escreva("\n DIVISÃO INTEIRA = " + tp.real_para_inteiro(numero1/numero2))
		escreva("\n DIVISÃO REAL =" + (numero1/numero2))
		escreva("\n RESTO DA DIVISAO = " + tp.real_para_inteiro(numero1) % tp.real_para_inteiro(numero2))
	}
}

Boa tarde Gabriel,
vc tem que comparar o valor do input a sua string. o JS tem a propriedade .value

if (nacao.value != 'Brasil') {
Contudo, ocorrerá um outro problema. E se o Usuário escrever brasil ao invés de Brasil.
acontecerá da condição ser falsa (no seu caso, verdadeiro ja que esta utilizando “!=“)
Para isso não ocorrer, faça a comparação ou com td maiúsculo ou tudo minúsculo pelo metodo .toUpperCase() ou .toLowerCase()
if (nacao.value.toLowerCase() != 'brasil') {

Espero ter ajudado,
Bons estudos !

Boa tarde Gustavo.
1- A variável jogadores é uma lista. vc esta chamando com keys (dicionário) em vez de index.

2- Quando vc copiar da sua IDE para o forum siga o seguinte processo:
1- na primeira linha do código, antes do primeiro caractere, ponha o cursor e pressione CODE que se encontra na barra de formatação de texto.
2- depois posicione o cursor após o ultimo caractere e pressionei novamente o CODE
3- vc notará que aparecerá uma crase ` no inicio e no final do código, isso significa que tudo que tiver neste intervalo permanecerá com a formatação original.

Boa tarde Luiz.
1-Sbore a biblioteca:
Quando vc abre a aba ajuda, ele te mostra a lista de bibliotecas disponíveis. Quantas consegue ver (eu contei 14 aqui) ?

2-Sobre a lentidão e versão:
Utilizo a versão atual também (v2.7.5) e roda de boa. Qual a configuração do seu computador e o sistema operacional ?

Boa tarde Bruna.
O arquivo que deseja copiar esta dentro de um pasta ? (digo que esta no campo folder)
se não estiver conseguindo com CTRL+C | CTRL+V, vc consegue manualmente ? (botão direito → copy ; botão direito → paste)

Qual a sua duvida em si ? qual parte do programa conseguiu concretizar ?

Boa tarde Antônio.
Primeiro uma dica, tente mandar seus códigos formatados.
-> copie e cole o seu código normalmente aqui.
-> em seguida selecione ele todo.
-> clique em CODE na barra de formatação de texto.
(isto fará com que as tags sejam postas tanto no começo quanto no final).

Quanto ao seu código:
realmente ele esta rodando sem nenhum problema e o método feito não esta errado. Contudo, esta gastando memoria desnecessariamente criando 2 variáveis para armazenar valores replicados em outras variáveis. Além de estar fazendo mais testes lógicos dentro dos condicionais.
(n1<n2 ou n1>n2 ou n2<1 ou n2>n1)
n1 < n2 -> n1 menor que n2
n1 > n2 -> n1 maior que n2
n2 < n1 -> n2 menor que n1
n2 > n1 -> n2 maior que n1
Se n1 é menor q n2 (n1 < n2), pode se afirmar que n2 é maior que n1 (n2 > n1)
se n1 é maior que n2 (n1 > n2), pode se afirmar que n2 é menor que n1 (n2 < n1)
ou seja, dos 4 testes lógicos, 2 são repetidos.

Quando vamos para os testes condicionais vc primeiro cria uma condição para determinar uma ordem. se não for esta ordem, ela inverte.
dai uma condição para escrever a primeira ordem e se não encaixar, dar a mensagem de iguais. total de 4 condições.
Sendo mais simples determinar a primeira condição n1 > n2 depois uma outra condição n1 < n2 e a terceira seria a sobra. (que só poderia um numero ser igual ao outro).

Não sei qual a resolução do professor. Mas baseado no seu, escrevi um código para vc analisar.

programa
{
	
	funcao inicio()
	{
		inteiro num1, num2
		escreva("Escreva um número: ")
		leia(num1)
		escreva("Escreva um segundo número: ")
		leia(num2)
		se (num1<num2) {
			escreva ("Es numeros em ordem são:", num1 ," - ",num2)
		}senao se (num2<num1) {
			escreva ("Es numeros em ordem são:", num2 ," - ",num1)
		}senao {
			escreva("Não tem como colocar esses valores em ordem, eles são iguais!")
		}
	}
}

fala irmão. Ótima pratica essa que esta fazendo de pegar os exercícios propostos e “por mais carga de dificuldades nele”
Continue com isso e verá que escreverá com mais fluidez…

Vamos as consideração e me desculpe qualquer erro… ( a tutora vai me corrigir e ponderar caso tenha algum/muitos erros da minha parte =) )

Antes de tudo utilize a formatação CODE para postar seus códigos aqui no fórum. isto permite que a formatação venha sem alterações, ficando muito mais legível. E caso seja a ponto de procurar uma falha, fica melhor para te dar um feedback.
Outra coisa é que não há muito o que questionar, pois o principal de uma aplicação é atender aos requisitos.

Eu estava escrevendo um monte de coisa, mas não iria adiantar muito pois você esta limitado pela nível matéria ainda. (dicionários, módulos, etc…)
Já que disse se tratar de um nível mais profissional, tente pegar o programa e aumentar o nível de validações para diminuir o erro no programa.
Ex. nome aceitar apenas letras (atualmente, se vc disser que o nome é 22 ele vai aceitar).
permita que o usuário digite ‘,’ (virgula) no peso ( a maioria das pessoas normalmente digita virgula ao invés do ponto)

Todo equipamento vem com manual e descrição. em alguma parte vai estar escrita qual o padrão dele.
ai basta comprar o padrão dos seus equipamentos com o padrão da sua rede.
se seu equipamento for 802.11b e sua rede 802.11n, seu equipamento vai ser limitado pelo próprio hardware.
o contrario a mesma coisa, se seu equipamento wifi for 802.11g e sua internet for de 120, seu próprio equipamento esta limitando a velocidade. (o mesmo vale para as frequências 5.0GHz e 2.4 GHz)

Muito bom dia Paulo.

Este exercício trata da utilização da estrutura de controle dentro da estrutura de repetição (para te exemplificar usarei enquanto, mas pode fazer com para ou faça).

vamos começar com a estrutura de repetição:
O exercício pede uma contagem que inicia no 1 e pede que informemos o fim.
sendo assim, precisaremos a variável de começo e de fim (como este exercício pede que seja escrito a progressão, podemos utilizar a variável ‘inicio’ como acumulador também (vai entender quando visualizar )).

	inteiro start = 1
	inteiro end

a variável end terá q ser informada pelo comando leia

agora a estrutura do enquanto ficara:

enquanto (start <= end){ // enquanto o start for menor ou igual a end, irá realizar o bloco.
     bloco //será nossa condição.
}

o enquanto irá fazer a contagem até o numero informado (end)

Agora ele nos pode para que todo numero múltiplo de 4 seja substituído por PIN!

para isso criaremos a condição
Como sabemos que o numero é divisível por 4? Todo numero que for divisível terá resto 0, então:

se ( start % 4 == 0 ) {
     bloco
}senao {
     bloco
}

se lembra do acumulador? ele será o numero que será dividido por 4, logo o start += 1 sempre que o bloco for executado. e dentro do bloco que for divisível por 4 irá escrever PIN e o que não for escreverá o acumulador
Abaixo segue o código (esta cru, sem as formatações… tente olhar ele após vc conseguir resolver o seu ou para tirar duvidas).

               inteiro start = 1
		inteiro end

		escreva("\nonde termina a contagem? ")
		leia (end)
	
		enquanto (start <= end){
			se (start % 4 == 0)
			{
				escreva ("PIN\n")
				start += 1	
			} senao {
				escreva (start, " ")
				start += 1
			}			
		}
		escreva("\nFIM DO PROGRAMA!\n")

Eu geralmente faço o seguinte.
Copio o codigo normalmente do IDLE para o forum (ele vai vir com os espaços certinhos.
seleciono todo o codigo e clico em CODE na aba de formatação.
isso fara com que seja posto a abertura e fechamento da formatação de uma vez (serve para todos as formatações)